Dvouvýběrový t-test

V minulém článku jsme otevřeli problematiku dvouvýběrových testů, tj. testů, které mezi sebou porovnávají dva statistické soubory. Konstatovali jsme, že existují tři varianty testu a každý má určené předpoklady, při kterých jej lze použít. Nyní se budeme zabývat situací, kdy máme dva soubory, přičemž pozorování z obou souborů nelze spárovat. Soubory tedy mohou mít i odlišný počet pozorování. Předpokládáme však, že soubory mají shodné rozptyly. V takovém případě použijeme dvouvýběrový t-test, někdy též označovaný jako dvouvýběrový Studentův test.

Soubor se všemi výpočty naleznete zde.

Levostranný dvouvýběrový t-test

Abychom si přesně ukázali odlišnost od párového t-testu, vyjdeme ze zadání podobného tomu minulému: Máme data o průměrném počtu vyrobených výrobků pracovníky ve dvou různých závodech, přičemž v jednom ze závodů jsou testovány nové výrobní procesy. Vedení společnosti potřebuje ověřit, zda nové výrobní postupy zvýšily produktivitu práce, a v závislosti na tom implementuje tyto postupy v dalších závodech. Ověřte na \alpha = 5 % hypotézu, že v závodě s novými výrobními postupy vyrobí pracovníci v průměru více výrobků, než v závodě s původními postupy, přičemž předpokládáme, že rozptyl průměrného počtu výrobků je v obou závodech stejný. Vedení v minulosti statisticky ověřilo, že před změnou procesů byli pracovníci v obou závodech v průměru stejně výkonní.

Protože porovnáváme dva různé závody, nemůžeme pozorování nijak spárovat. Naopak předpokládáme shodný rozptyl hodnot, proto můžeme použít dvouvýběrový t-test.

Soubor X_1 obsahuje pozorování ze závodu se starými postupy a soubor X_2 pozorování ze závodu s upravenými postupy. Příslušné střední hodnoty pak označíme \mu_{X_1}\mu_{X_2}. Nyní můžeme formulovat nulovou a alternativní hypotézu:

  • H_0: \mu_{X_1} = \mu_{X_2} \, . (Střední hodnota obou souborů je stejná.)
  • H_1: \mu_{X_1} < \mu_{X_2} \, . (Střední hodnota prvního souboru je nižší.)

Alternativní hypotéza nám tedy říká, že pracovníci vyrábějící podle nových postupů jsou v průměru výkonnější.

Definujme si statistiku testu T jako

T = \frac{\bar{X_1} - \bar{X_2}}{s_p \cdot \sqrt{\frac{1}{n1} + \frac{1}{n2}}} \, ,

kde n_1n_2 jsou rozsahy obou souborů a s_p určíme ze vzorce

s_p = \frac{(n_1 - 1)s^2_{X_1} + (n_2 - 1)s^2_{X_2}}{n_1 + n_2 - 2} \, ,

kde s^2_{X_1}s^2_{X_2} jsou výběrové rozptyly obou souborů. Statistika T má samozřejmě Studentovo rozdělení a kritický obor určíme ze vztahu

W = ( - \infty,  t_{\alpha} (n_1 + n_2 - 2) \rangle \, ,

Dvouvýběrový t-test můžeme v Excelu opět provést několika způsoby:

  • použitím doplňku Analýza dat,
  • použitím funkce T.TEST (nebo TTEST),
  • použitím funkcí pro kvantilovou a distribuční funkci Studentova rozdělení.

Modelová data najdete na obrázku níže, rozsah dat je n_1 = 40 n_2 = 30.

dvouvýběrový t-test data

Výpočet s využitím doplňku Analýza dat

Začneme s využitím doplňku Analýza dat. Ten spustíme kliknutím na tlačítko Analýza dat na panelu Data. Vybereme možnost Dvouvýběrový t-test s rovností rozptylů. Do políček 1. soubor a 2. soubor označíme umístění našich souborů. Pokud označíme i záhlaví tabulky, zaškrtneme možnost Popisky. V poli Alfa necháme výchozí hodnotu 0,05 a do pole Výstupní oblast vložíme hranici oblasti, do které budou vloženy výsledky.

dvouvýběrový t-test analýza dat

Výsledky pro naše data jsou na obrázku níže. Hodnota statistiky je pro oba typy testu stejná a najdeme ji v řádku t Stat, v našem případě tedy T = -2{,}8239. Při jednostranném testu nás dále zajímají řádky, které jsou označeny (1).

dvouvýběrový t-test analýza dat 2

Řádek P(T<=t) (1) obsahuje p-hodnotu testu. Opět ale platí, že na tuto hodnotu si musíme dát pozor, protože nemusí vždy odpovídat našemu zadání. V doplňku totiž neurčujeme alternativní hypotézu. Excel vrací tu ze dvou možných p-hodnot, která je menší než 0,5. V našem případě (a obecně v případě záporné hodnoty statistiky, resp. v případě vyšší hodnoty průměru prvního souboru) Excel vrací p-hodnotu pro levostranný t-test, což odpovídá našemu zadání. p-hodnota testu je tedy T = 0{,}0031. V posledním označeném řádku nalezneme hranici kritického oboru. Opět platí, že hranice je zobrazena v absolutní hodnotě. V našem případě máme levostranný test, odsekáváme tedy rozdělení statistiky zleva. Protože Studentovo rozdělení je symetrické kolem nuly, stačí k zobrazené hodnotě připsat minus, tj. kritický obor se nachází v intervalu:

W = ( - \infty,  - 1,6676 \rangle \, .

Využití funkce T.TEST (TTEST)

Výpočet s využitím funkce T.TEST (ve verzi 2007 a starších TTEST) je obdobný případu s párovým testem, měníme pouze poslední parametry. V případě nepárového testu se shodnými rozptyly souborů jako poslední parametr zadáváme 2. Jako první dva parametry zadáváme soubory s pozorováními a jako třeba parametr 1, protože provádíme jednostranný test. Výsledný vzorec je tedy:

T.TEST(A2:A41;B2:B31;1;2)

Funkce nám vrátí hodnotu 0,0031, což je, jak už víme, správný výsledek. Tato funkce se ale chová obdobně jako Analýza dat, tj. ze dvou možných p-hodnot vrací tu nižší. V případě záporné statistiky (tedy v případě, kdy je průměr druhého souboru vyšší než prvního) je tento výsledek správný, obecně to ale platit nemusí. Z tvaru vzorce statistiky vidíme, že statistika je záporná právě tehdy, pokud má druhý soubor vyšší průměr. Vzorec tedy můžeme zjednodušit tím, že se rozhodneme na základě porovnání průměrů obou souborů. Fuunkce podmínky:

=KDYŽ(E3<F3;T.TEST(A2:A41;B2:B31;1;2);1-T.TEST(A2:A41;B2:B31;1;2))

V případě funkce TTEST postupujeme obdobně, tj. jednodušší varianta vzorce je

TEST(A2:A41;B2:B31;1;2)

a obecně funguje vzorec

=KDYŽ(E3<F3;TTEST(A2:A41;B2:B31;1;2);1-TTEST(A2:A41;B2:B31;1;2))

Manuální výpočet

Poslední možností je provést výpočty “ručně”, tj. pomocí funkcí pro distribuční a kvantilovou funkci Studentova rozdělení. Pro výpočet statistiky potřebujeme průměr a výběrový rozptyl, které snadno vypočítáme pomocí funkcí PRŮMĚR a VAR.S (u starších verzí VAR.VÝBĚR).

Uveďme si nejprve vzorec pro výpočet statistiky:

=(E3-F3)/(E11*ODMOCNINA(1/E2+1/F2))

Výpočet v novějších verzích

Hranice kritického oboru určíme pomocí funkce T.INV, tj. pomocí kvantilové funkce Studentova rozdělení. Funkce T.INV se chová naprosto standardně. U levostranného testu odsekáváme kritický obor zleva, jako kvantil tedy zadáváme hladinu významnosti, tj. \alpha = 5 %. Počet stupňů volnosti je n_1 + n_2 - 2, tj. výsledný vzorece je:

=T.INV(E7;E2+F2-2)

Kritický obor je tedy:

W = ( - \infty,  - 1,6676 \rangle \, .

p-hodnotu určíme pomocí funkce T.DIST. U levostranného testu určujeme p-hodnotu zleva, použijeme tedy funkci Studentova rozdělení T.DIST. Tato funkce se opět chová zcela standardně, stačí tedy zadat hodnotu statistiky a počet stupňů volnosti a výsledek nijak neupravujeme:

=T.DIST(E12;E2+F2-2;PRAVDA)

Výpočet ve starších verzích

Ve starších verzích je výpočet poněkud náročnější. Máme k dispozici funkci TINV (název se liší tečkou oproti novější funkci), jejíž úskalí jsem podrobně popsal již v minulém článku. Funkce TINV pracuje s verzí Studentova rozdělení, jejíž hustota nabývá kladných hodnot pouze pro x > 0. Proto do vzorce musíme zadat hodnotu hladiny významnosti násobenou dvěma. Hranice kritického oboru pro levostranný test je záporná, protože před funkci musíme napsat minus. Výsledný vzorec je

=-TINV(E7*2;E2+F2-2)

Podobně záludná je funkce TDIST. Zadáme-li jako poslední parametr 1, nebudou hodnoty distribuční funkce dvojnásobné oproti Studentovu rozdělení. Stále ale funguje pouze v případě x > 0. V našem případě stačí hodnotu statistiky násobit minusem:

=TDIST(-E12;E2+F2-2;1)

Podobně jako u funkcí T.TEST a TTEST není výše uvedený vzorec obecně platný, protože může nastat případ, kdy bude hodnota statistiky kladná. Analogicky tedy provedeme úpravu, která je níže.

=KDYŽ(E12<0;TDIST(-E12;E2+F2-2;1);1-TDIST(E12;E2+F2-2;1))

Pravostranný test

Nyní si ukážeme postup při pravostranném testu. Upravme si nejprve předchozí zadání: Máme data o průměrném počtu výrobků, které neprošly kontrolou kvality (tj. zmetků), vyrobených ve dvou různých závodech, přičemž druhý závod postupuje podle upravených výrobních procesů. Předpokládáme, že počty mají v obou případech shodný rozptyl. Ověřte hypotézu, že změna výrobních postupů vedla ke snížení zmetkovosti.

Hypotézy našeho testu jsou následující:

  • H_0: \mu_{X_1} = \mu_{X_2} \, . (Střední hodnota obou souborů je stejná.)
  • H_1: \mu_{X_1} < \mu_{X_2} \, . (Střední hodnota prvního souboru je vyšší.)

Statistika testu zůstává stejná, kritický obor se přesunuje doprava, tj.:

W = \langle t_{1-\alpha} (n_1 + n_2 - 2) \infty ) \, ,

dvouvýběrový t-test data pravostranný

Výpočet s využitím doplňku Analýza dat

Výpočet spustíme pomocí stejného postupu, jako jsme si uvedli výše, tj. označíme oblasti s daty a výstupní oblast. Níže máme výsledek výpočtu. Hodnota statistiky je T = - 0{,}8626 a tentokrát máme správně určenou i hranici kritického oboru, kritický obor je tedy

W = \langle 1{,}6663, \infty ) \, .

dvouvýběrový t-test pravostranný analýza dat

Špatně je ale p-hodnota. Hodnota statistiky je záporná a protože kritický obor určujeme zprava, musí být p-hodnota vyšší než 0{,}5. Dochází zde tedy k problému, který jsme si popisovali výše. Tato p-hodnota by byla správná v případě levostranného testu. V případě pravostranného testu je ale 1 - 0{,}1956 = 0{,}8044.

Porovnání p-hodnot je na grafu níže. Červeně je označena p-hodnota levostranného testu, zeleně p-hodnota pravostranného.

dvouvýběrový t-test porovnání p-hodnot

Využití funkce T.TEST (TTEST)

Podobně jako Analýza dat, i funkce T.TEST v jednodušší variantě vrací chybný výsledek. Pří použití následujícího vzorce

T.TEST(A2:A41;B2:B35;1;2)

získáme hodnotu 0{,}1956, který by byla správná, pokud bychom dělali levostranný test.

Použijme tedy opět funkci podmínky. Tento vzorec je stejný jako výše s výjimkou znaménka u podmínky, které je obráceně.

=KDYŽ(E3>F3;T.TEST(A2:A41;B2:B35;1;2);1-T.TEST(A2:A41;B2:B35;1;2))

Ve starších verzích Excelu použijeme funkci TTEST, jejíž výstup je třeba obdobným způsobem upravit:

=KDYŽ(E3>F3;TTEST(A2:A41;B2:B35;1;2);1-TTEST(A2:A41;B2:B35;1;2))

Manuální výpočet

Vzorec pro výpočet statistiky zůstává stejný, proto rovnou přejdeme k dalším krokům.

Výpočet v novějších verzích

Kritický obor tentokrát určujeme zprava. Do kritického oboru budou patřit nejvyšší hodnoty z definičního oboru tak, že pravděpodobnost, že testová statistika nabude těchto hodnot, bude přesně \alpha, v našem případě \alpha = 0{,}05. Zbylé hodnoty, u nichž je tato pravděpodobnost 1 - \alpha = 1 - 0{,}05 = 0{,}95, jsou mimo kritický obor. Jak první parametr inverzní distribuční funkce Studentova rozdělení T.INV tedy zadáme 1 - \alpha, ostatní se nemění:

=T.INV(1-E7;E2+F2-2)

Kritický obor je tedy:

W = \langle 1{,}6663, \infty) \, .

p-hodnotu určíme pomocí funkce T.DIST a to opět směrem doprava, tj:

=1-T.DIST(E12;E2+F2-2;PRAVDA)

Můžeme rovněž použít pravostrannou distribuční funkci T.DIST.RT, která nám zápis trochu zjednoduší:

=T.DIST.RT(E12;E2+F2-2)

Výpočet ve starších verzích

Ve starších verzích musíme k určení hranice kritického oboru použít funkce TINV. Opět musíme hladinu významnosti násobit dvěma, před vzorec však nepíšeme minus, protože hranice kritického oboru musí být kladné číslo:

=TINV(E7*2;E2+F2-2)

Nakonec se musíme vypořádat s funkcí TDIST. Tato funkce si opět neporadí se zápornou statistikou, kterou je třeba převést na kladné číslo. Funkce ale nepracuje s informací o tom, jestli se nacházíme nalevo nebo napravo od nuly, vrací tedy vždy hodnotu menší než 0{,}5. Máme-li tedy zápornou statistiku, musíme výsledek funkce odečíst od jedné, abychom získali plochu pod hustotou od hodnoty statistiky směrem doprava. Obecně funkční vzorec opět získáme pomocí funkce podmínky:

=KDYŽ(G12>0;TDIST(G12;E2+F2-2;1);1-TDIST(-G12;E2+F2-2;1))

Oboustranný test

Poslední variantou je oboustranný test. Opět si upravíme zadání příkladu: Máme data o počtu vyrobených výrobků pracovníky za jednu směnu ve dvou různých závodech jedné společnosti. Ověřte na \alpha = 5 % hypotézu, že mezi těmito dvěma závody existuje statisticky významný rozdíl v průměrném počtu vyrobených výrobků.

V tomto případě se v zadání nepřikláníme na jednu ani na druhou stranu, tj. alternativní hypotéza platí jak v případě, že první závod bude v průměru lepší, tak i v případě, že bude v průměru horší.

Hypotézy našeho testu jsou následující:

  • H_0: \mu_{X_1} = \mu_{X_2} \, . (Střední hodnota obou souborů je stejná.)
  • H_1: \mu_{X_1} \neq \mu_{X_2} \, . (Střední hodnota souborů se liší.)

Vzorec pro výpočet statistiky zůstává stejný, kritický obor se (jako v případě předchozích oboustranných testů) skládá z dvou intervalů:

W = ( -\infty,  t_{\frac{\alpha}{2}} (n_1 + n_2 - 2) \rangle \cup \langle t_{1-\frac{\alpha}{2}} (n_1 + n_2 - 2), \infty ) \, .

List s daty je na obrázku níže.

dvouvýběrový t-test oboustranný data

Všimněte si, že rozsah obou souborů je stejný, vzhledem k charakteru dat ale nelze použít párový t-test.

Výpočet s využitím doplňku Analýza dat

Výpočet spustíme obdobným postupem jako výše.

dvouvýběrový t-test oboustranný analýza dat

Níže vidíme výsledky. Hodnotu testové statistiky nalezneme stále na stejném místě, tj. T = 2{,}2873. Dále nás budou zajímat poslední dva řádky. Poslední řádek obsahuje hranici kritického oboru, resp. jeho horní hranici. Dolní hranice je v absolutní hodnotě stejná jako horní, je však záporná, neboť Studentovo rozdělení je symetrické.

dvouvýběrový t-test oboustranný analýza dat 2

Kritický obor tedy je

W = ( -\infty, - 2{,}0106 \rangle \cup \langle -2{,}0106, \infty ) \, .

V předposledním řádku je p-hodnota. Ta je v případě oboustranného testu vždy správná, tj. p-hodnota našeho testu je 0{,}0266. Za tabulky vidíme, že

  • p-hodnota je menší než hladina významnosti (0{,}05 > 0{,}0266),
  • hodnota statistiky se nachází v kritickém oboru (2{,}2873 \in \langle 2{,}0106, \infty) ),

zamítáme tedy nulovou hypotézu. Na hladině významnosti \alpha = 5 % jsme tedy prokázali, že mezi oběma závody existuje rozdíl. Nemůžeme však tvrdit, že by první závod byl lepší než druhý, pouze existenci rozdílu!

Využití funkce T.TEST

V případě oboustranného testu je použití funkce T.TEST jednoduché. Jako poslední parametr zadáváme 2. Vrácená p-hodnota je vždy správná bez ohledu na hodnotu statistiky, tj. vzorec pro funkci T.TEST je

=T.TEST(A2:A26;B2:B26;2;2)

a pro starší funkcí TTEST pak

=TTEST(A2:A26;B2:B26;2;2)

Manuální výpočet

Výpočet statistiky opět zůstává stejný.

Výpočet v novějších verzích Excelu

V případě oboustranného testu určujeme dolní a horní hranici kritického oboru. Při použití funkce T.INV určíme dolní hranici jako

=T.INV(E7/2;E2+F2-2)

a horní hranici, která se od dolní liší pouze znaménkem, pak

=T.INV(1-E7/2;E2+F2-2)

Alternativně je samozřejmě možné před vzorec pro dolní hranici napsat minus nebo použít funkci T.INV.RT.

Určení p-hodnoty je nyní tentokrát mírně složitější. U oboustranného testu určujeme p-hodnotu vždy směrem k bližšímu kraji číselné osy, tj. pro záporné statistiky doleva a pro kladné doprava. Výsledek poté musíme násobit dvěma. Při použití funkce KDYŽ můžeme vytvořit obecně platný vzorec jako

=KDYŽ(E12<0;T.DIST(E13;E2+F2-2;PRAVDA);1-T.DIST(E13;E2+F2-2;PRAVDA))*2

Alternativně je možné použít funkci MIN, protože horní podmínky vždy vybere tu nižší z obou variant

=MIN(T.DIST(E13;E2+F2-2;PRAVDA);1-T.DIST(E13;E2+F2-2;PRAVDA))*2

Chceme-li si ušetřit práci, můžeme použít funkci T.DIST.2T. To je obdoba funkce TDIST ze starších verzí Excelu, tj. pracuje s upraveným Studentovým rozdělením, jehož hustota nabývá kladných hodnot pouze pro kladná čísla, je zde však dvojnásobná oproti běžná hustotě. Dáme-li této funkci absolutní hodnotu statistiky, pak nám tedy vrátí rovnou p-hodnotu.

=T.DIST.2T(ABS(E13);E2+F2-2)

Výpočet ve starších verzích

Ve starších verzích musíme použít funkci TINV. Tentokrát zadáváme přímo hladinu významnosti, ale nedělíme ji dvěma. Před vzorec napíšeme minus:

=-TINV(E7;E2+F2-2)

Vzorec pro horní hranici je téměř totožný, pouze neobsahuje znak minus:

=TINV(E7;E2+F2-2)

K určení p-hodnoty použijeme funkci TDIST. Vzorec je v tomto případě jednodušší, podobně jako u funkce T.DIST.2T. Funkci předáme absolutní hodnotu statistiky a funkce pak vždy vrátí p-hodnotu určenou “správným směrem”. Jako poslední parametr zadáme 2, což zajistí hodnoty distribuční funkce dvojnásobné oproti běžnému Studentovu rozdělení, nemusíme tedy výsledek násobit dvěma.

=TDIST(ABS(F13);E2+F2-2;2)

2 Comments

Vít Černohouz May 5, 2018 at 9:01 am

Kez bychom meli takhle vzorne vypracovane materialy na statistice. Muzou lide tvoje clanky volne sirit?

Like

Leave a Reply

Name and email address are required. Your email address will not be published.

Fill in your details below or click an icon to log in:

WordPress.com Logo

You are commenting using your WordPress.com account. Log Out /  Change )

Google+ photo

You are commenting using your Google+ account. Log Out /  Change )

Twitter picture

You are commenting using your Twitter account. Log Out /  Change )

Facebook photo

You are commenting using your Facebook account. Log Out /  Change )

w

Connecting to %s

You may use these HTML tags and attributes:

<a href="" title="" rel=""> <abbr title=""> <acronym title=""> <b> <blockquote cite=""> <cite> <code> <del datetime=""> <em> <i> <pre> <q cite=""> <s> <strike> <strong> 

%d bloggers like this: