T-test a jeho využití

Zásadním omezením z-testu, který jsme si popisovali minule, je nutnost znát rozptyl testovaného souboru. V realitě velikost rozptylu velmi často neznáme, a tak se musíme spokojit s jeho odhadem. V takovém případě musíme využít určitou “modifikaci” z-testu, která se nazývá t-test.

Soubor s daty i výpočty si můžete stáhnout zde: t-test.

Začněme s oboustranným t-testem. Uvažujeme následující příklad: Máme zařízení, které vyrábí součástku určité délky. Zařízení má určitou chybovost, jejíž přesnou velikost neznáme. Chyby mají normální rozdělení. Zařízení bylo nastaveno pracovníkem a my chceme ověřit, že pracovník nastavil správnou délku součástky, tj. 190 mm. Pro ověření jsme vybrali a přeměřili náhodný soubor dvaceti součástek.

Obecné principy testování hypotéz, které jsme si popsali v článku o z-testu, zůstávají v platnosti. Definujeme si tedy nulovou a alternativní hypotézu:

  • H_0: \mu = 190 \, \mathrm{mm}. (Slovně: Střední hodnota statistického souboru je 190 mm.)
  • H_0: \mu \neq 190 \, \mathrm{mm}. (Střední hodnota statistického souboru je není 190 mm.)

Statistiku získáme ze vzorce

t = \frac{\bar{x} - \mu_0}{s} \sqrt{n} \, ,

kde \bar{x} je průměr našeho vzorku, \mu_0 je teoretická (testovaná) střední hodnota, a n je rozsah náhodného výběru. Proměnná s je odhad rozptylu základního souboru a pro tento odhad využijeme výběrový rozptyl

s = \frac{\sum\limits^{n}_{i=1} (x_i -\bar{x})}{n-1} \, ,

kde x_i je i-tá hodnota v našem výběru. Jmenovatel zlomku může být pro někoho matoucí, protože bychom spíše očekávali hodnotu n. Má to však svůj dobrý důvod. Pokud bychom do jmenovatele umístili n, pak střední hodnota našeho odhadu by byla menší, než skutečná hodnota rozptylu. Blíže to popíšu v nějakém z dalších článků.

Naše statistika t nemá tentokrát normované rozdělení, ale má takzvané Studentovo neboli t rozdělení. Toto rozdělení má jeden parametr, který značíme \nu . V našem případě platí vztah

\nu = n - 1 \, .

t rozdělení má podobné vlastnosti jako normované normální: jeho střední hodnota je 0 a je symetrické kolem 0. Čím vyšší je hodnota parametru \nu , tím více se distribuční funkce t rozdělení blíží normovanému normálnímu. Často se uvádí, že u t-testu můžeme pro \nu > 30 použít normované normální rozdělení. Pokud však i pro tyto hodnoty použijeme t rozdělení, nejedná se o chybu.

Kvantilvou funkci t rozdělení s (\nu) stupni volnosti budeme značit  t_{p} (\nu). Kritický obor testu určíme ze vzorce

W = ( - \infty, t_{\frac{\alpha}{2}} \left(n-1 \right) \rangle \cup \langle t_{1-\frac{\alpha}{2}} \left( n - 1 \right), \infty ) \, ,

kde \alpha značí hladinu významnosti testu.

Nyní již víme vše, co potřebujeme, a můžeme se vrhnout na provedení testu v Excelu.

Oboustranný t-test v Excelu

Od verze 2010 obsahuje Excel přepracovanou sadu funkcí pro provádění statistických výpočtů. Používáte-li tedy verzi 2010 a vyšší, doporučuji vám tyto novější funkce využívat, protože jejich použití je v řadě případů jednodušší. Uživatelé starších verzí mají k dispozici pouze starší sadu funkcí. My si ukážeme postup pro obě varianty.

Náš testovací soubor máme uložený v buňkách A1 až A20. Test provedeme na \alpha = 5 % , tuto hodnotu máme v buňce D6.

t-test data 2

Výpočet ve verzi Excel 2010 a vyšší

K provedení t-test potřebujeme výběrovou směrodatnou odchylku souboru. Směrodatnou odchylku získáme vzorcem

=SMODCH.VÝBĚR.S(A1:A20)

Hodnotu si uložíme do buňky D4. Teoretickou střední hodnotu máme v buňce D10, průměr náhodného souboru v buňce D3. Nyní určíme kritický obor. Využijeme kvantilovou funkci Excelu pro t rozdělení – T.INV. Dolní hranici kritického oboru získáme vzorcem

=T.INV(D6/2;D2-1)

a horní hranici vzorcem

=T.INV(1-D6/2;D2-1)

Hodnoty se liší pouze znaménkem, protože (jak už jsme uvedli) je t rozdělení symetrické kolem 0. Ze získaných hodnot můžeme kritický obor zapsat intervalem:

W =  ( - \infty, t_{0,025} \left(19 \right) \rangle \cup \langle t_{0,975} ( 19 ), \infty ) = ( - \infty, -2,0930 \rangle \cup \langle 2,0930, \infty ) \, .

Nyní si určíme hodnotu statistiky (pomocí vzorce t = \frac{\bar{x} - \mu_0}{s} \sqrt{n}):

=(D3-D5)/D4*ODMOCNINA(D2)

Hodnota statistiky je -0,92 a výsledek máme v buňce D10. Protože statistika leží mimo kritický obor, nulovou hypotézu nezamítáme. Určeme si ještě p-hodnotu testu. K tomu využijeme distribuční funkci t rozdělení T.DIST:

=T.DIST(D10;D2-1;PRAVDA) * 2

V tomto případě určujeme p-hodnotu jako plochu pod hustotou statistiky směrem doleva a násobíme ji dvěma. Pokud bychom však měli hodnotu statistiky vyšší než 0, je třeba určovat p-hodnotu jako plochu od statistiky směrem doprava. K tomu můžeme využít funkci T.DIST.RT, která určuje kvantily t rozdělení zprava. Správná hodnota bude vždy ta menší. Chceme-li, aby si Excel zvolil tuto hodnotu sám, použijeme funkci MIN:

=MIN(T.DIST(D10;D2-1;PRAVDA);T.DIST.RT(D10;D2-1))*2

Výpočet ve verzi Excel 2007 a nižší

Následující postup lze aplikovat Excelu 2007 nebo starších, ale dostupný je i v novějších. K odhadu směrodatné odchylky použijeme funkci SMODCH.VÝBĚR:

=SMODCH.VÝBĚR(A1:A20)

Kritický obor určíme pomocí funkce TINV (funkce se od předchozí liší chybějící tečkou v názvu). Do této funkce ale nezadáváme kvantil rozdělení, ale přímo hladinu významnosti. Navíc hodnotu hladiny významnosti ani nedělíme dvěma. Výsledek funkce je vždy kladný, pro spodní hranici tedy napíšeme před funkci znaménko minus:

=-TINV(D6;D2-1)

Pravá hranice už je bez znaménka:

=TINV(D6;D2-1)

Funkce TINV totiž nepracuje se standardním t rozdělením, ale rozdělením, která má nenulovou hustotu pouze pro x > 0. Hustota je pak dvojnásobkem hustoty standardního t rozdělení, protože musí být splněna podmínka, že plocha pod hustotou musí být rovna 1.

Nyní vypočteme statistiku testu:

=(D3-D5)/E4*ODMOCNINA(D2)

Hodnota statistiky je opět -0,92, tj. statistika leží mimo kritický obor a nulovou hypotézu nezamítáme. Pro určení p-hodnoty využijeme funkci TDIST, která určuje hodnotu distribuční funkce t rozdělení. Zadáme-li jako poslední parametr dvojku, Excel využije výše zmíněnou “dvojnásobnou” distribuční funkci a výsledek pak nemusíme násobit dvěma.

=TDIST(ABS(D10);D2-1;2)

Jednostranný t-test

Nyní si stručně popíšeme postup jednostrannách variant t-testu. Při jednostranné variantě máme odlišnou alternativní hypotézu. Alternativní hypotéza při levostranném testu tvrdí, že střední hodnota základního souboru je menší než testovaná hodnota. Při pravostranném testu naopak tvrdí, že skutečná střední hodnota je vyšší. Testovat budeme na $\alpha = 0,05$.

Levostranný t-test

Začneme se levostranným t-test. Při něm se rozhodujeme mezi těmito hypotézami:

  • H_0: \mu = 190 \, \mathrm{mm}.
  • H_0: \mu < 190 \, \mathrm{mm}.

Testová statistika zůstává stejná a ve prospěch alternativní hypotézy mluví její velmi malé hodnoty. Kritický obor tedy “odsekáváme” zleva, tj. kritický obor vyjádřený intervalem má tvar

W = ( - \infty, t_{\alpha} \left(n-1 \right) \rangle \, .

t-test data a výsledky lev.PNG

Výpočet ve verzi Excel 2010 a novějším

Směrodatnou odchylku určíme stejným postupem jako výše

=SMODCH.VÝBĚR.S(A1:A20)

Kritický obor má pouze jednu hranici a \alpha-tý kvantil t rozdělení. Ten snadno určíme pomocí funkce T.INV:

=T.INV(D6;D2-1)

Kritický obor můžeme vyjádřit intervalem jako

W = ( - \infty, t_{0,05} \left(19 \right) \rangle =   ( - \infty, -1,7291 \rangle \, .

Vzorec pro výpočet statistiky zůstává stejný:

=(D3-D5)/D4*ODMOCNINA(D2)

Statistika má hodnotu -2,1310. Protože hodnota statistiky leží v kritickém oboru, zamítáme nulovou hypotézu. Na $\alpha = 0,05$ tedy tvrdíme, že zařízení bylo nastaveno chybně. Zbývá určit p-hodnotu, kterou získáme opět pomocí funkce T.DIST:

=T.DIST(D9;D2-1;PRAVDA)

P-hodnota testu je 0,0232. To potvrzuje závěr o zamítnutí nulový hypotézy na $\alpha = 0,05$. Nulovou hypotézu bychom nezamítli hladinách významnosti $\alpha < 0,0232$.

Výpočet ve verzi Excel 2007 a starší

Směrodatnou odchylku určíme podle stejného vzorce jako u obostranného testu:

=SMODCH.VÝBĚR(A1:A20)

Při určování kritické hodnoty pro oboustranný t-test jsme zadávali přímo hladinu významnosti a nemuseli ji dělit dvěma. Nyní tedy musíme funkci T.INV zadat hladinu významnosti násobenou dvěma. Dále před funkci dáme znaménko minus, abychom získali záporné číslo.

=-TINV(2*D6;D2-1)

Vzorec pro hodnotu statistiky zůstává stejný

=(D3-D5)/E4*ODMOCNINA(D2)

Jako poslední určíme p-hodnotu. Opět využijeme funkci TDIST. Tentokrát jako poslední parametr zadáváme jedničku.

=TDIST(ABS(D9);D2-1;1)

Pravostranný t-test

Při pravostranném testu se rozhodujeme mezi těmito hypotézami:

  • H_0: \mu = 190 \, \mathrm{mm}.
  • H_0: \mu > 190 \, \mathrm{mm}.

Kritický obor nyní “odsekáváme” zprava, tj. kritický obor vyjádřený intervalem má tvar

W = \rangle t_{\alpha} \left(n-1 \right), \infty ) \, .

Výpočet statistiky a výběrové směrodatné odchylky zůstává stejný, určíme tedy pouze pouze hranice kritického oboru a p-hodnotu.

t-test data a výsledky prav

Výpočet ve verzi Excel 2010 a novější

K určení hranice kritického oboru použijeme opět funkci T.INV, tentokrát kritický obor začíná na 95%ním kvantinu t rozdělení, tj. jako první parametr zadávání 1 - \alpha:

=T.INV(1-D6;D2-1)

Hodnota statistiky je nyní 0,1301. Tato hodnota neleží v kritickém oboru, nulovou hypotézu tedy nezamítáme. K určení p-hodnoty využijeme funkci T.DIST.RT, se kterou jsme se seznámili již výše. Tato funkce vrací plochu pod funkcí hustoty od zadaného bodu směrem doprava.

=T.DIST.RT(D9;D2-1)

Alternativně můžeme využít funkci T.DIST. Tato funkce vrací obsah plochy směrem doleva. Protože celková plocha má obsah 1, potřebou hodnotu získáme odečtením výsledku funkce T.DIST od jedničky

=1-T.DIST(D9;D2-1;PRAVDA)

P-hodnota testu je 0,4489.

Výpočet ve verzi Excel 2007 a starší

Máme-li starší verzi Excelu nebo nechceme-li z nějakého důvodu použít funkci T.INV, využijeme opět funkci TINV. Opět zadáváme hladinu významnosti násobenou dvěma. Tentokrát nepoužíváme znaménko minus, protože hranické kritického oboru je kladné číslo.

=TINV(2*D6;D2-1)

Určení p-hodnoty je v tomto případě stejné jako u předchozího postupu, tj. použijeme vzorec

=TDIST(ABS(D9);D2-1;1)

Trackbacks and Pingbacks

[…] předcházejících článcích jsme rozebírali z-test a t-test. Oba testy slouží k otestování hypotézy o střední hodnotě a liší se pouze předpokladem o […]

Like

Leave a Reply

Name and email address are required. Your email address will not be published.

Fill in your details below or click an icon to log in:

WordPress.com Logo

You are commenting using your WordPress.com account. Log Out / Change )

Twitter picture

You are commenting using your Twitter account. Log Out / Change )

Facebook photo

You are commenting using your Facebook account. Log Out / Change )

Google+ photo

You are commenting using your Google+ account. Log Out / Change )

Connecting to %s

You may use these HTML tags and attributes:

<a href="" title="" rel=""> <abbr title=""> <acronym title=""> <b> <blockquote cite=""> <cite> <code> <del datetime=""> <em> <i> <pre> <q cite=""> <s> <strike> <strong> 

%d bloggers like this: